Topic: Downloaded all required file for GW3 but.......

[BlazinBud]

Greeting's,  I dl'd all the required mission scripts and shiplist/fighterlist ect.  Only thing I'm having probs. with is a Models.bat file,  were do I need to place this?

[Corbomite]

You should really just get the installer, but that file goes to your Desktop. Double click it and it will install the files to your Models folder.

[KBFLordKrueg]

Well, instructions on that is here. http://bozobits.com/forums/viewtopic.php?t=5827
But I must agree, just download the installer form the rules page here: http://mkroll.asta.chicago.il.us/
It does all the work and makes it very easy to rmove the files after the campaign by simply running the uninstaller.

[BlazinBud]

What does it modify in your models folder?

[KBFLordKrueg]

Read the instructional thread, it explans it. Mostly it adds the model folders for the new Klingon, Mirak and Fed P/Fs.
Also, these downloads were updated yesterday. I would strongly recommend you download the installer so you get the correct lists. I don't know if the older links have been updated with the newer lists.

[BlazinBud]

Yea I would use the installer but I got TNG installed also,  so I figured I would just add files myself so I could delete them at later date.  I really dont feel like reinstalling OP with TNG again LOL.  It can be a pain sometimes.  Thx for replies thou  

[Bonk]

All your answers are here (NSIS installer script):

Code: [Select]

Name "GW3"
OutFile "GW3.exe"
CRCCheck on
SetCompressor lzma

LicenseText "Information and Acknowledgements"
LicenseData "Ack.rtf"

InstallDirRegKey HKLM "SOFTWARE\Taldren\Starfleet Command Orion Pirates" "Directory"
DirText "Please confirm the installation directory:"

Var opplus_version

Section "Install"

ReadRegStr $opplus_version HKLM "SOFTWARE\FireSoul\opplus" "version"
StrCmp $opplus_version "3.4" Opplus_installed Opplus_not_installed


Opplus_installed:

CreateDirectory "$INSTDIR\GW3_backup"

CreateDirectory "$INSTDIR\GW3_backup\Assets"

CreateDirectory "$INSTDIR\GW3_backup\Assets\Specs"
CopyFiles "$INSTDIR\Assets\Specs\shiplist.txt" "$INSTDIR\GW3_backup\Assets\Specs" 2491
CopyFiles "$INSTDIR\Assets\Specs\ftrlist.txt" "$INSTDIR\GW3_backup\Assets\Specs" 29

CreateDirectory "$INSTDIR\GW3_backup\MetaAssets"
CopyFiles "$INSTDIR\MetaAssets\shiplist.txt" "$INSTDIR\GW3_backup\MetaAssets" 2491
CopyFiles "$INSTDIR\MetaAssets\ftrlist.txt" "$INSTDIR\GW3_backup\MetaAssets" 29

CreateDirectory "$INSTDIR\GW3_backup\Assets\Models"
CopyFiles "$INSTDIR\Assets\Models\model.siz" "$INSTDIR\GW3_backup\Assets\Models" 32


SetOutPath $INSTDIR\MetaAssets
File /r Shiplist\*.*
SetOutPath $INSTDIR\Assets\Specs
File /r Shiplist\*.*

SetOutPath $INSTDIR\Assets
File /r Models

CreateDirectory "$INSTDIR\Assets\Models\fpf"
CopyFiles "$INSTDIR\Assets\Models\fff\*.*" "$INSTDIR\Assets\Models\fpf" 815
Rename "$INSTDIR\Assets\Models\fpf\fff.mod" "$INSTDIR\Assets\Models\fpf\fpf.mod"
Rename "$INSTDIR\Assets\Models\fpf\fff_brk.mod" "$INSTDIR\Assets\Models\fpf\fpf_brk.mod"

CreateDirectory "$INSTDIR\Assets\Models\hpf"
CopyFiles "$INSTDIR\Assets\Models\hff\*.*" "$INSTDIR\Assets\Models\hpf" 1130
Rename "$INSTDIR\Assets\Models\hpf\hff.mod" "$INSTDIR\Assets\Models\hpf\hpf.mod"
Rename "$INSTDIR\Assets\Models\hpf\hff_brk.mod" "$INSTDIR\Assets\Models\hpf\hpf_brk.mod"

CreateDirectory "$INSTDIR\Assets\Models\ipf"
CopyFiles "$INSTDIR\Assets\Models\iff\*.*" "$INSTDIR\Assets\Models\ipf" 1130
Rename "$INSTDIR\Assets\Models\ipf\iff.mod" "$INSTDIR\Assets\Models\ipf\ipf.mod"
Rename "$INSTDIR\Assets\Models\ipf\iff_brk.mod" "$INSTDIR\Assets\Models\ipf\ipf_brk.mod"

CreateDirectory "$INSTDIR\Assets\Models\kpf"
CopyFiles "$INSTDIR\Assets\Models\kff\*.*" "$INSTDIR\Assets\Models\kpf" 1050
Rename "$INSTDIR\Assets\Models\kpf\kff.mod" "$INSTDIR\Assets\Models\kpf\kpf.mod"
Rename "$INSTDIR\Assets\Models\kpf\kff_brk.mod" "$INSTDIR\Assets\Models\kpf\kpf_brk.mod"

CreateDirectory "$INSTDIR\Assets\Models\zpf"
CopyFiles "$INSTDIR\Assets\Models\zff\*.*" "$INSTDIR\Assets\Models\zpf" 980
Rename "$INSTDIR\Assets\Models\zpf\zff.mod" "$INSTDIR\Assets\Models\zpf\zpf.mod"
Rename "$INSTDIR\Assets\Models\zpf\zff_brk.mod" "$INSTDIR\Assets\Models\zpf\zpf_brk.mod"

SetOutPath $INSTDIR\Assets
File /r Scripts


WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GW3" "DisplayName" "GW3 Files"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GW3" "UninstallString" '"$INSTDIR\GW3_Uninstall.exe"'

SetOutPath $INSTDIR
WriteUninstaller "GW3_Uninstall.exe"
CreateDirectory "$SMPROGRAMS\GW3"
CreateShortCut "$SMPROGRAMS\GW3\Uninstall GW3 Files.lnk" "$INSTDIR\GW3_Uninstall.exe"

Goto Finished_install

Opplus_not_installed:
MessageBox MB_OK|MB_ICONSTOP "OP+ 3.4 not found! GW3 requires OP+ 3.4, please install it first. (GW3 not installed.)" IDOK Finished_install

Finished_install:

SectionEnd


Section "Uninstall"


MessageBox MB_YESNO "Are you sure you want to uninstall GW3?" IDNO Doneuninstall

MessageBox MB_YESNO "Would you like to keep the installed multiplayer scripts?" IDYES Donescripts

Delete "$INSTDIR\Assets\Scripts\Met_NW17PatrolAllied.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW17PatrolEnemy.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW18HomeworldAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWAlliedPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWBaseStationAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWBattleStationAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWEnemyPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWOneOnOne.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWPlanetAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWPlayerPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWStarbaseAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NWStarbaseConstruction.scr"
Delete "$INSTDIR\Assets\Scripts\NWMissionConfig.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW1Scout.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW2HoldingAction.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW7BaseStationAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW7BattleStationAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW7StarbaseAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW8ShipAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW9PlanetaryAssault.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW10Patrol.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW10PatrolAllied.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW14Enigma.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW16ShipDefense.scr"
Delete "$INSTDIR\Assets\Scripts\Met_NW17Patrol.scr"

Delete "$INSTDIR\Assets\Scripts\Kar_hlPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_hPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_jPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_MeleeAction.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_SkirmishAction.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_Ambushee.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_ConvoyEscort.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_ConvoyRaid.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_cpPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_dPatrol.scr"
Delete "$INSTDIR\Assets\Scripts\Kar_ePatrol.scr"

Donescripts:


RMDir /r "$INSTDIR\Assets\Models\fpf"
RMDir /r "$INSTDIR\Assets\Models\hpf"
RMDir /r "$INSTDIR\Assets\Models\ipf"
RMDir /r "$INSTDIR\Assets\Models\kpf"
RMDir /r "$INSTDIR\Assets\Models\zpf"

CopyFiles "$INSTDIR\GW3_backup\Assets\Specs\shiplist.txt" "$INSTDIR\Assets\Specs"
CopyFiles "$INSTDIR\GW3_backup\Assets\Specs\ftrlist.txt"  "$INSTDIR\Assets\Specs"

CopyFiles "$INSTDIR\GW3_backup\MetaAssets\shiplist.txt" "$INSTDIR\MetaAssets"
CopyFiles "$INSTDIR\GW3_backup\MetaAssets\ftrlist.txt" "$INSTDIR\MetaAssets"

CopyFiles "$INSTDIR\GW3_backup\Assets\Models\model.siz" "$INSTDIR\Assets\Models"

RMDir /r "$INSTDIR\GW3_backup"


DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GW3"

Delete "$SMPROGRAMS\GW3\*.*"
RMDir "$SMPROGRAMS\GW3"

Delete "$INSTDIR\GW3_Uninstall.exe"

Doneuninstall:

SectionEnd


[KBFLordKrueg]

Ok, np. Read this thread then, it tells you where to put what.
http://bozobits.com/forums/viewtopic.php?t=5827

[Bonk]

Yea I would use the installer but I got TNG installed also,  so I figured I would just add files myself so I could delete them at later date.  I really dont feel like reinstalling OP with TNG again LOL.  It can be a pain sometimes.  Thx for replies thou 

You should be fine to use the installer, as illustrated above: it backs up and restores your CURRENT files (shiplist, fighterlist, model.siz), creates five new model folders and copies stock ones to it, it also installs some of the latest NW and EEK scripts.
When uninstalled it will restore your specs files (shiplist, fighterlist, model.siz) delete the new model folders and offer you the choice to keep or delete the installed missions.  (The missions is the only potential place where files may conflict as I did not check for and backup every mission file, they will overwrite if the same ones are present. If you chose to remove the missions on uninstall, you may need to reinstall your EEK or NW mission packs. You could back up your missions folder manually before installing if you like, but reinstalling the mission packs is easier...)

Also, a manual install of the latest files will work just fine of course. (the two zip files linked on the website)

[BlazinBud]

Thx for all the support.....   

[Bonk]

You're welcome! 
[/color][/glow]